Sul Delphic Phenomenon avevo predisposto questo listato, forse mi rimaneva qualche piccolo problema... poi non ho avuto più il tempo per guardarci.
Può essere ugualmente uno spunto.
Saluti a tutti.
M.Mazziero
{************************************************************************************
© 2003 Maurizio Mazziero
Partner di Trading Library Formazione Srl
Il presente materiale ha esclusivamente finalità didattiche
e non può in alcun modo essere considerato come sollecitazione
alla raccolta del pubblico risparmio. Le tecniche e i risultati
presentati non costituiscono alcuna garanzia per l’eventuale
applicazione delle strategie descritte sui mercati reali.
L’attività speculativa comporta notevoli rischi economici
e chi la esercita lo fa sotto la propria e completa responsabilità.
Trading System: DPh long
La strategia si avvale di 2 medie mobili (1 semplice a 18 periodi
e 1 semplice a 40 periodi). Dopo il loro incrocio al rialzo si
attende che il prezzo ritracci sotto la media mobile a 18 periodi,
il successivo superamento della media costituisce il segnale di
acquisto.
Lo stop loss iniziale è costituito dalla violazione della media
a 40 periodi, una volta che la posizione va in guadagno si
procederà con un trailing stop posizionato al valore intermedio
fra la media a 40 e la media a 18 periodi.
La chiusura di posizione è determinata in trailing stop.
Questa tecnica trae spunto da strategie di autori americani
con ulteriori adattamenti al mercato italiano,
per maggiori approfondimenti è possibile consultare il libro:
IL TRADING FACILE CON LE MEDIE MOBILI
Scot Lowry
Trading Library
************************************************************************************}
Var: Sma18(0), // Media mobile
Sma40(0), // Media mobile
ParSma18(18), // Parametro media mobile
ParSma40(40), // Parametro media mobile
valuebuy(0), // prezzo di acquisto
valuesell(0), // prezzo di vendita
valuetrail(0), // valore del trailing stop
valuestop(0), // valore dello stop loss
truecompra1(0), // Flag di condizione parziale in acquisto
truecompra2(0); // Flag di condizione parziale in acquisto
// Costruzione delle medie mobili
Sma18 = MOV(Close, ParSma18, S);
Sma40 = MOV(Close, ParSma40, S);
SECTION_ENTERLONG:
if Crossover(Sma18,Sma40) then
truecompra1=1; // incrocio media 18 su 40
Colorbar(yellow); // coloro la barra per verifica primo setup
endif;
if sma18<sma40 then // se avviene un incrocio contrario ferma il setup
truecompra1=0;
Colorbar(black);
endif;
if within(H,sma40,sma18) and truecompra1=1 then // il prezzo deve scendere
truecompra2=1; // sotto la media 18
Colorbar(blue);
else
truecompra2=0; // nel caso scenda anche sotto la sma40
Colorbar(black); // si annulla il setup
endif;
if C<sma40 then // anche nel caso la chiusura sia sotto
truecompra2=0; // la sma40 si annulla il setup
Colorbar(black);
endif;
if truecompra1=1 and truecompra2=1 then // deve aprire sotto la media
valuebuy=sma18;
EnterLong(NextBar, valuebuy); // COMPRA al superamento della media a 18
valuestop=sma40; // valore dello stop loss
endif;
if Positiondir=1 then
ColorBar(green);
endif;
END_SECTION
SECTION_EXITLONG:
Colorbar(black); // forza il colore delle barre a nero
truecompra1=0;
truecompra2=0; // Azzeriamo le variabili d'acquisto
ValueTrail=Sma18-((Sma18-Sma40)/2); // valore del trailing stop
if C<Addperc(PositionValue,3) then
ValueSell=Addtick(ValueStop,-3); // Calcola il valore di Sell con lo stop
else
ValueSell=Addtick(ValueTrail,-3); // Calcola il valore di Sell con il trail
endif;
if ValueSell>L then
// se il minimo scende sotto il valore di vendita
ColorBar(red); // colorazione barra di chiusura posizione
ExitLong(Bar,ValueSell); // Liquida posizione long
if Positiondir=1 then // liquida in ogni caso se il valore viene saltato
ExitLong(Bar, Atclose);
endif;
endif;
END_SECTION
